Артём Санников

Oracle поддерживает три разновидности коллекций. Несмотря на ряд общих характеристик, все эти разновидности обладают специфическими особенностями.

• Ассоциативные массивы. Это одномерные неограниченные разреженные коллекции, состоящие из однородных элементов, доступные только в PL/SQL. Этот термин выбран потому, что предложение INDEX BY может использоваться для индексирования содержимого коллекций посредством значений типа VARCHAR2 или PLS_INTEGER.
• Вложенные таблицы. Так называются одномерные несвязанные коллекции, также состоящие из однородных элементов. Первоначально они заполняются полностью, но позднее из-за удаления некоторых элементов могут стать разреженными. Вложенные таблицы могут определяться и в PL/SQL, и в базах данных (например, в качестве столбцов таблиц). Вложенные таблицы представляют собой мультимножества, то есть элементы вложенной таблицы не упорядочены.
• Массив типа VARRAY. Подобно двум другим типам коллекций, массивы VARRAY (массивы переменной длины) также являются одномерными коллекциями, состоящими из однородных элементов. Однако их размер всегда ограничен, и они не бывают разреженными. Как и вложенные таблицы, массивы VARRAY используются и в PL/SQL, и в базах данных. Однако порядок их элементов при сохранении и выборке, в отличие от вложенных таблиц, сохраняется.

Примеры коллекций

Сейчас будут рассмотренные относительно простые примеры всех разновидностей коллекций с описанием их основных характеристик.

Ассоциативный массив

В этом примере объявляется тип ассоциативного массива, а затем коллекция, основанная на этом типе. Коллекция заполняется четырьмя элементами, после чего выполняется перебор её содержимого и вывод символьных строк. Подробно разъяснение приведено после примера.

DECLARE
   TYPE list_of_names_t IS TABLE OF person.first_name%TYPE
      INDEX BY PLS_INTEGER;
   happyfamily   list_of_names_t;
   l_row PLS_INTEGER;
BEGIN
   happyfamily (2020202020) := 'Eli';
   happyfamily (-15070) := 'Steven';
   happyfamily (-90900) := 'Chris';
   happyfamily (88) := 'Veva';

   l_row := happyfamily.FIRST;

    WHILE (l_row IS NOT NULL)
    LOOP
      DBMS_OUTPUT.put_line (happyfamily (l_row));
      l_row := happyfamily.NEXT (l_row);
   END LOOP;
END;

/*
Результат:
Chris
Steven
Veva
Eli
*/

Вложенная таблица

Следующий пример начинается с объявления типа вложенной таблицы как типа уровня схемы. На основании этого типа в блоке PL/SQL объявляются три вложенные таблицы. Имена членов семьи сохраняются во вложенной таблице happyfamily, имена детей — во вложенной таблице children, после чего команда MULTISET EXCEPT используется для извлечения из вложенной таблицы happyfamily только имен родителей. Подробное разъяснение приводится после примера.

REM Раздел A

CREATE TYPE list_of_names_t IS TABLE OF VARCHAR2 (100);
Type created.

REM Раздел B

DECLARE
   happyfamily   list_of_names_t := list_of_names_t ();
   children      list_of_names_t := list_of_names_t ();
   parents       list_of_names_t := list_of_names_t ();
BEGIN
   happyfamily.EXTEND (4);
   happyfamily (1) := 'Eli';
   happyfamily (2) := 'Steven';
   happyfamily (3) := 'Chris';
   happyfamily (4) := 'Veva';

   children.EXTEND;
   children (1) := 'Chris';
   children.EXTEND;
   children (2) := 'Eli';

   parents := happyfamily MULTISET EXCEPT children;

   FOR l_row IN parents.FIRST .. parents.LAST
   LOOP
      DBMS_OUTPUT.put_line (parents (l_row));
   END LOOP;
END;

/*
Результат:
Steven
Veva
*/

VARRAY

Данный пример демонстрирует использование типов VARRAY в качестве столбцов реляционной таблицы. Сначала мы объявляем два разных типа VARRAY уровня схемы, после чего создаем реляционную таблицу family с двумя столбцами VARRAY. Наконец, в коде PL/SQL заполняются две локальные коллекции, используемые при выполнении операции INSERT с таблицей family. Подробное разъяснение приводится после примера.

REM Раздел A

CREATE TYPE first_names_t IS VARRAY (2) OF VARCHAR2 (100);
Type created.

CREATE TYPE child_names_t IS VARRAY (1) OF VARCHAR2 (100);
Type created.

REM Раздел B

CREATE TABLE family (
     surname VARCHAR2(1000)
   , parent_names first_names_t
   , children_names child_names_t
);

Table created.

REM Раздел C

DECLARE
   parents    first_names_t := first_names_t ();
   children   child_names_t := child_names_t ();
BEGIN
   parents.EXTEND (2);
   parents (1) := 'Samuel';
   parents (2) := 'Charina';
   --
   children.EXTEND;
   children (1) := 'Feather';

   --
   INSERT INTO family
               ( surname, parent_names, children_names )
        VALUES ( 'Assurty', parents, children );
END;

PL/SQL procedure successfully completed.

SQL> SELECT * FROM family;

/*
SURNAME
PARENT_NAMES
CHILDREN_NAMES
--------------------------------------------
Assurty
FIRST_NAMES_T('Samuel', 'Charina')
CHILD_NAMES_T('Feather')
*/

Метки: Oracle, Коллекции.